AIR/Flex: 2010年12月アーカイブ

ActionScriptの標準ライブラリではZIPファイルの解凍機能は提供されていないので、自分で作るか、他人様が作成されて公開されているものを使うしかない。

勉強がてら作ってみるのは面白いのだが、今回の仕事はそういうライブラリが存在していることを前提に作業工数を見積もっているので、

FZip - http://codeazur.com.br/lab/fzip/

という、フリーのライブラリを使ってみた。（商用利用も問題なさげ）

日本語のドキュメントがほとんど存在していないため、英語のサンプルソースを見てどうにかするしかなかったので少し時間がかかったが、例えば任意のZIPファイルを解凍するだけなら以下のようなソースになる。

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"
    initialize="initProc()"
    layout="absolute" width="480" height="208">
    <mx:Label x="183" y="18" text="ZIP解凍 テスト" fontSize="18" id="Title"/>
    <mx:TextArea x="23" y="54" width="428" height="122" id="Message"/>

    <mx:Script>
    <![CDATA[

    import deng.fzip.FZip;    // ZIP操作ライブラリ
    import flash.events.*; 
    import flash.net.URLRequest;

    public var Fzip:FZip;
    public var ZipFileName:String    = "data/cont/ds.zip";
    public var ZipDirName:String    = "data/cont/ds/";

    private function initProc():void {

        Fzip = new FZip();

        var request:URLRequest = new URLRequest();
        var file:File = File.applicationStorageDirectory.resolvePath(ZipFileName);
        request.url = file.nativePath;

        Message.text    += "FN=" + file.nativePath + "\n";

        Fzip.addEventListener(Event.COMPLETE, loadComplete);
        Fzip.addEventListener(IOErrorEvent.IO_ERROR, onIOError);

        Fzip.load(request);
 
    }
 
    public function loadComplete(evt:Event):void {

        var file:File;
        var stream:FileStream;

        for(var i:int=0; i < Fzip.getFileCount(); i++){

            Message.text    += Fzip.getFileAt(i).filename + "\n";

            file = File.applicationStorageDirectory.resolvePath(ZipDirName + Fzip.getFileAt(i).filename);       
            stream    = new FileStream();
            try {
                stream.open(file,FileMode.WRITE);
                stream.writeBytes(Fzip.getFileAt(i).content);
                Message.text    += "File Output Success. " + file.nativePath + "\n";
            }
            catch(error:IOError) {
                Message.text    += "File Output Error.\n";
            }
            finally {
                stream.close();
            }

        }

    }

    private function onIOError(evt:IOErrorEvent):void {

        Message.text    += "There was an IO Error.\n";

    }

    ]]>
    </mx:Script>

</mx:WindowedApplication>

これで、ばっりち applicationStorageDirectory 以下の data/cont/ds/ ディレクトリ以下にファイルが展開される。
FileStream は、子ディレクトリが存在していなければ勝手に掘ってくれるので楽だ。

「FileReference.download メソッドだとダイアログが開いちゃうな」に書いたように、インターネット上から自動でデータ取ってきて、ファイルの保存まで自動で行おうとすると、URLLoader でデータ取ってきて、FileStream で書き出すしかないみたい。

こんな感じ。

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"
    initialize="initProc()"
    layout="absolute" width="348" height="202">
    <mx:Label x="79" y="24" text="ダウンロードテスト" width="191" fontSize="18" textAlign="center" id="Title"/>
    <mx:TextArea x="39" y="60" width="266" height="113" id="Message" text=""/>

    <mx:Script>
    <![CDATA[

    import flash.events.*; 
    import flash.net.URLRequest;
    import flash.net.URLLoader;

    public static const FILE_GET_URI:String    = "http://www.exsample.jp/data/ds.zip";

    public var FileGet:URLLoader;
    public var ZipFileName:String    = "data/cont/ds.zip";

    private function initProc():void {

        FileGet = new URLLoader();
        FileGet.dataFormat    = URLLoaderDataFormat.BINARY; // バイナリ宣言

        FileGet.addEventListener(IOErrorEvent.IO_ERROR, onIOError);
        FileGet.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
        FileGet.addEventListener(Event.COMPLETE, onComplete);

        Message.text    += FILE_GET_URI + " Download Start.\n";

        var request:URLRequest    = new URLRequest();
        request.url    = FILE_GET_URI;
        FileGet.load(request);

    }

    private function onIOError(evt:IOErrorEvent):void {
        Message.text    += "There was an IO Error.\n";
    }

    private function onSecurityError(evt:Event):void {
        Message.text    += "There was a security error.\n";
    }

    private function onComplete(evt:Event):void {
        Message.text    += "File was successfully downloaded.\n";
        Message.text    += "SIZE=" + FileGet.bytesTotal + "\n";

        var file:File = File.applicationStorageDirectory.resolvePath(ZipFileName);
        var stream:FileStream    = new FileStream();
        try {
            stream.open(file,FileMode.WRITE);
            stream.writeBytes(FileGet.data);
            Message.text    += "File Output Success. " + file.nativePath + "\n";
        }
        catch(error:IOError) {
            Message.text    += "File Output Error.\n";
        }
        finally {
            stream.close();
        }
    }

    ]]>
    </mx:Script>

</mx:WindowedApplication>

ちなみに、
FileGet.dataFormat = URLLoaderDataFormat.BINARY;
でバイナリデータ通信だと設定するのを忘れていて、writeBytes する時に

TypeError: Error #1034: Type Coercion failed: cannot convert "PKCDT to flash.utils.ByteArray.

というエラーが出ちゃってハマった。(^^;

FileGet.data を  ByteArray にわざわざ型キャストしてみたり色々やってみたが駄目で、結局、通信モードをバイナリ型にするのを忘れていただけだった。とほほ。

ActionScript も日頃頻繁に使ってるわけではないので、こういうのがまだ身に染み付いてないんだよなあ。

AIR アプリ起動時に、自動でインターネット上のサーバから最新のファイルをダウンロードしてくる・・・という処理が作りたかったので、試しに FileReference.download() メソッドを使ってみたのだが、これだと保存するファイル名を指定するダイアログが開いてしまうね。
どうも、download メソッドだと、download して即ファイル保存をするということか。

ダウンロード後は一旦メモリ上に保持して、プログラム内で静的に指定しているパスに save メソッド使って書き出すような処理にしたいのだが、さて、どうすんのかね？

取りあえず、備忘録としてソースも貼っとく。

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"
    initialize="initProc()"
    layout="absolute" width="348" height="202">
    <mx:Label x="79" y="24" text="ダウンロードテスト" width="191" fontSize="18" textAlign="center" id="Title"/>
    <mx:TextArea x="39" y="60" width="266" height="113" id="Message" text=""/>

    <mx:Script>

    <![CDATA[

    import flash.events.*; 
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public static const FILE_GET_URI:String    = "http://www.exsample.jp/data/ds.zip";
    public var FileRef:FileReference;

    private function initProc():void {
        FileRef = new FileReference();
        FileRef.addEventListener(IOErrorEvent.IO_ERROR, onIOError);
        FileRef.addEventListener(SecurityErrorEvent.SECURITY_ERROR,
                                        onSecurityError);
        FileRef.addEventListener(Event.COMPLETE, onComplete);

        Message.text    += FILE_GET_URI + " Download Start.\n";

        var request:URLRequest    = new URLRequest();
        request.url    = FILE_GET_URI;
        FileRef.download(request);
    }

    private function onIOError(evt:IOErrorEvent):void {
        Message.text    += "There was an IO Error.\n";
    }

    private function onSecurityError(evt:Event):void {
        Message.text    += "There was a security error.\n";
    }

    private function onComplete(evt:Event):void {
        Message.text    += "File was successfully downloaded.\n";
    }

    ]]>

    </mx:Script>

</mx:WindowedApplication>